571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
62 lines
1.4 KiB
Nix
62 lines
1.4 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, perlPackages
|
|
, shortenPerlShebang
|
|
}:
|
|
|
|
perlPackages.buildPerlPackage rec {
|
|
pname = "shelldap";
|
|
version = "1.5.1";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "mahlonsmith";
|
|
repo = "shelldap";
|
|
rev = "refs/tags/v${version}";
|
|
hash = "sha256-67ttAXzu9pfeqjfhMfLMb9vWCXTrE+iUDCbamqswaLg=";
|
|
};
|
|
|
|
buildInputs = with perlPackages; [
|
|
AlgorithmDiff
|
|
AuthenSASL
|
|
IOSocketSSL
|
|
perl
|
|
perlldap
|
|
TermReadLineGnu
|
|
TermShell
|
|
TieIxHash
|
|
YAMLSyck
|
|
];
|
|
|
|
nativeBuildInputs = lib.optional stdenv.hostPlatform.isDarwin shortenPerlShebang;
|
|
|
|
prePatch = ''
|
|
touch Makefile.PL
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
install -Dm555 -t $out/bin shelldap
|
|
runHook postInstall
|
|
'';
|
|
|
|
postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
|
|
shortenPerlShebang $out/bin/shelldap
|
|
'';
|
|
|
|
# no make target 'test', not tests provided by source
|
|
doCheck = false;
|
|
|
|
outputs = [ "out" ];
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/mahlonsmith/shelldap/";
|
|
description = "Handy shell-like interface for browsing LDAP servers and editing their content";
|
|
changelog = "https://github.com/mahlonsmith/shelldap/blob/v${version}/CHANGELOG";
|
|
license = with licenses; [ bsd3 ];
|
|
maintainers = with maintainers; [ clerie tobiasBora ];
|
|
platforms = platforms.unix;
|
|
mainProgram = "shelldap";
|
|
};
|
|
}
|