571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
64 lines
1.6 KiB
Nix
64 lines
1.6 KiB
Nix
{ stdenv
|
|
, lib
|
|
, fetchFromGitLab
|
|
, gmp
|
|
, python3
|
|
, tune ? false # tune to hardware, impure
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "0.9.2";
|
|
pname = "zn_poly";
|
|
|
|
# sage has picked up the maintenance (bug fixes and building, not development)
|
|
# from the original, now unmaintained project which can be found at
|
|
# http://web.maths.unsw.edu.au/~davidharvey/code/zn_poly/
|
|
src = fetchFromGitLab {
|
|
owner = "sagemath";
|
|
repo = "zn_poly";
|
|
rev = version;
|
|
hash = "sha256-QBItcrrpOGj22/ShTDdfZjm63bGW2xY4c71R1q8abPE=";
|
|
};
|
|
|
|
buildInputs = [
|
|
gmp
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
python3 # needed by ./configure to create the makefile
|
|
];
|
|
|
|
# name of library file ("libzn_poly.so")
|
|
libbasename = "libzn_poly";
|
|
libext = stdenv.hostPlatform.extensions.sharedLibrary;
|
|
|
|
makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
|
|
|
|
# Tuning (either autotuning or with hand-written parameters) is possible
|
|
# but not implemented here.
|
|
# It seems buggy anyways (see homepage).
|
|
buildFlags = [ "all" "${libbasename}${libext}" ];
|
|
|
|
configureFlags = lib.optionals (!tune) [
|
|
"--disable-tuning"
|
|
];
|
|
|
|
# `make install` fails to install some header files and the lib file.
|
|
installPhase = ''
|
|
mkdir -p "$out/include/zn_poly"
|
|
mkdir -p "$out/lib"
|
|
cp "${libbasename}"*"${libext}" "$out/lib"
|
|
cp include/*.h "$out/include/zn_poly"
|
|
'';
|
|
|
|
doCheck = true;
|
|
|
|
meta = with lib; {
|
|
homepage = "https://web.maths.unsw.edu.au/~davidharvey/code/zn_poly/";
|
|
description = "Polynomial arithmetic over Z/nZ";
|
|
license = with licenses; [ gpl3 ];
|
|
maintainers = teams.sage.members;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|