571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
46 lines
1.1 KiB
Nix
46 lines
1.1 KiB
Nix
{ lib, stdenv, fetchFromGitHub, copyPkgconfigItems, makePkgconfigItem }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "stb";
|
|
version = "unstable-2023-01-29";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "nothings";
|
|
repo = "stb";
|
|
rev = "5736b15f7ea0ffb08dd38af21067c314d6a3aae9";
|
|
hash = "sha256-s2ASdlT3bBNrqvwfhhN6skjbmyEnUgvNOrvhgUSRj98=";
|
|
};
|
|
|
|
nativeBuildInputs = [ copyPkgconfigItems ];
|
|
|
|
pkgconfigItems = [
|
|
(makePkgconfigItem rec {
|
|
name = "stb";
|
|
version = "1";
|
|
cflags = [ "-I${variables.includedir}/stb" ];
|
|
variables = rec {
|
|
prefix = "${placeholder "out"}";
|
|
includedir = "${prefix}/include";
|
|
};
|
|
inherit (meta) description;
|
|
})
|
|
];
|
|
|
|
dontBuild = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/include/stb
|
|
cp *.h $out/include/stb/
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Single-file public domain libraries for C/C++";
|
|
homepage = "https://github.com/nothings/stb";
|
|
license = licenses.publicDomain;
|
|
platforms = platforms.all;
|
|
maintainers = [ ];
|
|
};
|
|
}
|