571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
66 lines
1.7 KiB
Nix
66 lines
1.7 KiB
Nix
{ lib, stdenv, cmake, fetchFromGitLab
|
|
, json_c, libsodium, libxml2, ncurses }:
|
|
|
|
let
|
|
rev = "22796663dcad81684ab24308d9db570f6781ba2c";
|
|
|
|
in stdenv.mkDerivation rec {
|
|
name = "mpw-${version}-${builtins.substring 0 8 rev}";
|
|
version = "2.6";
|
|
|
|
src = fetchFromGitLab {
|
|
owner = "MasterPassword";
|
|
repo = "MasterPassword";
|
|
sha256 = "1f2vqacgbyam1mazawrfim8zwp38gnwf5v3xkkficsfnv789g6fw";
|
|
inherit rev;
|
|
};
|
|
|
|
sourceRoot = "${src.name}/platform-independent/c/cli";
|
|
|
|
postPatch = ''
|
|
rm build
|
|
substituteInPlace mpw-cli-tests \
|
|
--replace '/usr/bin/env bash' ${stdenv.shell} \
|
|
--replace ./mpw ./build/mpw
|
|
'';
|
|
|
|
cmakeFlags = [
|
|
"-Dmpw_version=${version}"
|
|
"-DBUILD_MPW_TESTS=ON"
|
|
];
|
|
|
|
nativeBuildInputs = [ cmake ];
|
|
|
|
buildInputs = [ json_c libxml2 libsodium ncurses ];
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
install -Dm755 mpw $out/bin/mpw
|
|
install -Dm644 ../mpw.completion.bash $out/share/bash-completion/completions/_mpw
|
|
install -Dm644 ../../../../README.md $out/share/doc/mpw/README.md
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
# Some tests are expected to fail on ARM64
|
|
# See: https://gitlab.com/spectre.app/cli/-/issues/27#note_962950844 (mpw is a predecessor to spectre-cli and this issue is relevant to mpw as well)
|
|
doCheck = !(stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isAarch64);
|
|
|
|
checkPhase = ''
|
|
runHook preCheck
|
|
|
|
../mpw-cli-tests
|
|
|
|
runHook postCheck
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Stateless password management solution";
|
|
mainProgram = "mpw";
|
|
homepage = "https://masterpasswordapp.com/";
|
|
license = licenses.gpl3;
|
|
platforms = platforms.unix;
|
|
};
|
|
}
|