571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
62 lines
1.8 KiB
Nix
62 lines
1.8 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchurl
|
|
, fetchpatch
|
|
, SDL
|
|
, autoreconfHook
|
|
, glib
|
|
, pkg-config
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "libvisual";
|
|
version = "0.4.1";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/libvisual/${pname}-${version}.tar.gz";
|
|
hash = "sha256-qhKHdBf3bTZC2fTHIzAjgNgzF1Y51jpVZB0Bkopd230=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
patches = [
|
|
# pull upstream fix for SDL1 cross-compilation.
|
|
# https://github.com/Libvisual/libvisual/pull/238
|
|
(fetchpatch {
|
|
name = "sdl-cross-prereq.patch";
|
|
url = "https://github.com/Libvisual/libvisual/commit/7902d24aa1a552619a5738339b3823e90dd3b865.patch";
|
|
hash = "sha256-84u8klHDAw/q4d+9L4ROAr7XsbXItHrhaEKkTEMSPcc=";
|
|
# remove extra libvisual prefix
|
|
stripLen = 1;
|
|
# pull in only useful configure.ac changes.
|
|
excludes = [ "Makefile.am" ];
|
|
})
|
|
(fetchpatch {
|
|
name = "sdl-cross-pc.patch";
|
|
url = "https://github.com/Libvisual/libvisual/commit/f79a2e8d21ad1d7fe26e2aa83cea4c9f48f9e392.patch";
|
|
hash = "sha256-8c7SdLxXC8K9BAwj7DzozsZAcbs5l1xuBqky9LJ1MfM=";
|
|
# remove extra libvisual prefix
|
|
stripLen = 1;
|
|
})
|
|
];
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [ autoreconfHook pkg-config ];
|
|
buildInputs = [ SDL glib ];
|
|
|
|
configureFlags = lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
|
|
# Remove once "sdl-cross-prereq.patch" patch above is removed.
|
|
"--disable-lv-tool"
|
|
] ++ lib.optionals (!stdenv.buildPlatform.canExecute stdenv.hostPlatform) [
|
|
"ac_cv_func_malloc_0_nonnull=yes"
|
|
"ac_cv_func_realloc_0_nonnull=yes"
|
|
];
|
|
|
|
meta = {
|
|
description = "Abstraction library for audio visualisations";
|
|
homepage = "https://sourceforge.net/projects/libvisual/";
|
|
license = lib.licenses.lgpl21Plus;
|
|
platforms = lib.platforms.linux;
|
|
};
|
|
}
|