571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
41 lines
1.1 KiB
Nix
41 lines
1.1 KiB
Nix
{ lib
|
|
, stdenv
|
|
, fetchFromGitHub
|
|
, meson
|
|
, ninja
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "frozen";
|
|
# pin to a newer release if frozen releases again, see cesanta/frozen#72
|
|
version = "unstable-2021-02-23";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "cesanta";
|
|
repo = "frozen";
|
|
rev = "21f051e3abc2240d9a25b2add6629b38e963e102";
|
|
hash = "sha256-BpuYK9fbWSpeF8iPT8ImrV3CKKaA5RQ2W0ZQ03TciR0=";
|
|
};
|
|
|
|
nativeBuildInputs = [ meson ninja ];
|
|
|
|
# frozen has a simple Makefile and a GN BUILD file as building scripts.
|
|
# Since it has only two source files, the best course of action to support
|
|
# cross compilation is to create a small meson.build file.
|
|
# Relevant upstream issue: https://github.com/cesanta/frozen/pull/71
|
|
# We also remove the GN BUILD file to prevent conflicts on case-insesitive
|
|
# file systems.
|
|
preConfigure = ''
|
|
rm BUILD
|
|
cp ${./meson.build} meson.build
|
|
'';
|
|
|
|
meta = {
|
|
homepage = "https://github.com/cesanta/frozen";
|
|
description = "Minimal JSON parser for C, targeted for embedded systems";
|
|
license = lib.licenses.asl20;
|
|
maintainers = with lib.maintainers; [ thillux ];
|
|
platforms = lib.platforms.unix;
|
|
};
|
|
}
|