571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
39 lines
1.4 KiB
Nix
39 lines
1.4 KiB
Nix
{ lib, fetchurl, appimageTools, makeWrapper }:
|
|
|
|
let
|
|
pname = "framesh";
|
|
version = "0.6.9";
|
|
src = fetchurl {
|
|
url = "https://github.com/floating/frame/releases/download/v${version}/Frame-${version}.AppImage";
|
|
hash = "sha256-SsQIAg5DttvNJk1z+GJq4+e0Qa/j+VEKPV2bPA6+V8A=";
|
|
};
|
|
|
|
appimageContents = appimageTools.extractType2 {
|
|
inherit pname version src;
|
|
};
|
|
in
|
|
appimageTools.wrapType2 {
|
|
inherit pname version src;
|
|
nativeBuildInputs = [ makeWrapper ];
|
|
|
|
extraInstallCommands = ''
|
|
install -m 444 -D ${appimageContents}/frame.desktop $out/share/applications/frame.desktop
|
|
install -m 444 -D ${appimageContents}/frame.png \
|
|
$out/share/icons/hicolor/512x512/apps/frame.png
|
|
wrapProgram "$out/bin/${pname}" \
|
|
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform=wayland --enable-features=WaylandWindowDecorations}}"
|
|
|
|
substituteInPlace $out/share/applications/frame.desktop \
|
|
--replace 'Exec=AppRun' 'Exec=${pname}'
|
|
'';
|
|
|
|
meta = {
|
|
description = "Native web3 interface that lets you sign data, securely manage accounts and transparently interact with dapps via web3 protocols like Ethereum and IPFS";
|
|
homepage = "https://frame.sh/";
|
|
downloadPage = "https://github.com/floating/frame/releases";
|
|
license = lib.licenses.gpl3Only;
|
|
platforms = [ "x86_64-linux" ];
|
|
maintainers = with lib.maintainers; [ nook ];
|
|
};
|
|
}
|