571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
62 lines
1.5 KiB
Nix
62 lines
1.5 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, testers, berglas }:
|
|
|
|
let
|
|
skipTests = {
|
|
access = "Access";
|
|
create = "Create";
|
|
delete = "Delete";
|
|
list = "List";
|
|
read = "Read";
|
|
replace = "Replace";
|
|
resolver = "Resolve";
|
|
revoke = "Revoke";
|
|
update = "Update";
|
|
};
|
|
|
|
skipTestsCommand =
|
|
builtins.foldl' (acc: goFileName:
|
|
let testName = builtins.getAttr goFileName skipTests; in
|
|
''
|
|
${acc}
|
|
substituteInPlace pkg/berglas/${goFileName}_test.go \
|
|
--replace "TestClient_${testName}_storage" "SkipClient_${testName}_storage" \
|
|
--replace "TestClient_${testName}_secretManager" "SkipClient_${testName}_secretManager"
|
|
''
|
|
) "" (builtins.attrNames skipTests);
|
|
in
|
|
|
|
buildGoModule rec {
|
|
pname = "berglas";
|
|
version = "2.0.6";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "GoogleCloudPlatform";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
sha256 = "sha256-aTUMEn/QkPzvAyUvMxyqLl6KWFHs+dQK0VDqYv36AGM=";
|
|
};
|
|
|
|
vendorHash = "sha256-n/NOAmOOoZMFZGreUGNgrZ3XGbhmI52KtgakcJ/SJIc=";
|
|
|
|
ldflags = [
|
|
"-s"
|
|
"-w"
|
|
"-X github.com/GoogleCloudPlatform/berglas/v2/internal/version.version=${version}"
|
|
];
|
|
|
|
postPatch = skipTestsCommand;
|
|
|
|
passthru.tests = {
|
|
version = testers.testVersion {
|
|
package = berglas;
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "Tool for managing secrets on Google Cloud";
|
|
homepage = "https://github.com/GoogleCloudPlatform/berglas";
|
|
license = licenses.asl20;
|
|
mainProgram = "berglas";
|
|
};
|
|
}
|