571c71e6f7
We are migrating packages that meet below requirements:
1. using `callPackage`
2. called path is a directory
3. overriding set is empty (`{ }`)
4. not containing path expressions other than relative path (to
makenixpkgs-vet happy)
5. not referenced by nix files outside of the directory, other
than`pkgs/top-level/all-packages.nix`
6. not referencing nix files outside of the directory
7. not referencing `default.nix` (since it's changed to `package.nix`)
8. `outPath` doesn't change after migration
The tool is here: https://github.com/Aleksanaa/by-name-migrate.
52 lines
1.4 KiB
Nix
52 lines
1.4 KiB
Nix
{ stdenv, lib, fetchFromGitHub, cairo, libxkbcommon
|
|
, pango, fribidi, harfbuzz, pkg-config, scdoc
|
|
, ncursesSupport ? true, ncurses
|
|
, waylandSupport ? true, wayland, wayland-protocols, wayland-scanner
|
|
, x11Support ? true, xorg
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "bemenu";
|
|
version = "0.6.23";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "Cloudef";
|
|
repo = "bemenu";
|
|
rev = finalAttrs.version;
|
|
hash = "sha256-0vpqJ2jydTt6aVni0ma0g+80PFz+C4xJ5M77sMODkSg=";
|
|
};
|
|
|
|
strictDeps = true;
|
|
nativeBuildInputs = [ pkg-config scdoc ]
|
|
++ lib.optionals waylandSupport [ wayland-scanner ];
|
|
|
|
buildInputs = [
|
|
cairo
|
|
fribidi
|
|
harfbuzz
|
|
libxkbcommon
|
|
pango
|
|
] ++ lib.optional ncursesSupport ncurses
|
|
++ lib.optionals waylandSupport [ wayland wayland-protocols ]
|
|
++ lib.optionals x11Support [
|
|
xorg.libX11 xorg.libXinerama xorg.libXft
|
|
xorg.libXdmcp xorg.libpthreadstubs xorg.libxcb
|
|
];
|
|
|
|
makeFlags = ["PREFIX=$(out)"];
|
|
|
|
buildFlags = ["clients"]
|
|
++ lib.optional ncursesSupport "curses"
|
|
++ lib.optional waylandSupport "wayland"
|
|
++ lib.optional x11Support "x11";
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/Cloudef/bemenu";
|
|
description = "Dynamic menu library and client program inspired by dmenu";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ crertel ];
|
|
mainProgram = "bemenu";
|
|
platforms = with platforms; linux;
|
|
};
|
|
})
|