mirror of
https://github.com/golang/go
synced 2024-10-02 04:28:33 -06:00
10425507fd
After a little build coordinator change, this will get us sharding of the race builder. Update #11074 Change-Id: I4c55267563b6f5e213def7dd6707c837ae2106bf Reviewed-on: https://go-review.googlesource.com/10845 Reviewed-by: Andrew Gerrand <adg@golang.org>
53 lines
1.0 KiB
Batchfile
53 lines
1.0 KiB
Batchfile
:: Copyright 2013 The Go Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style
|
|
:: license that can be found in the LICENSE file.
|
|
|
|
:: race.bash tests the standard library under the race detector.
|
|
:: http://golang.org/doc/articles/race_detector.html
|
|
|
|
@echo off
|
|
|
|
setlocal
|
|
|
|
if exist make.bat goto ok
|
|
echo race.bat must be run from go\src
|
|
:: cannot exit: would kill parent command interpreter
|
|
goto end
|
|
:ok
|
|
|
|
set GOROOT=%CD%\..
|
|
call make.bat --dist-tool >NUL
|
|
if errorlevel 1 goto fail
|
|
.\cmd\dist\dist env -w -p >env.bat
|
|
if errorlevel 1 goto fail
|
|
call env.bat
|
|
del env.bat
|
|
|
|
if %GOHOSTARCH% == amd64 goto continue
|
|
echo Race detector is only supported on windows/amd64.
|
|
goto fail
|
|
|
|
:continue
|
|
call make.bat --no-banner --no-local
|
|
if %GOBUILDFAIL%==1 goto end
|
|
echo # go install -race std
|
|
go install -race std
|
|
if errorlevel 1 goto fail
|
|
|
|
go tool dist test -no-rebuild -race
|
|
|
|
if errorlevel 1 goto fail
|
|
goto succ
|
|
|
|
:fail
|
|
set GOBUILDFAIL=1
|
|
echo Fail.
|
|
goto end
|
|
|
|
:succ
|
|
echo All tests passed.
|
|
|
|
:end
|
|
if x%GOBUILDEXIT%==x1 exit %GOBUILDFAIL%
|
|
|