mirror of
https://github.com/golang/go
synced 2024-10-04 11:11:21 -06:00
4b7d5f0b94
Make sure that we're moving or zeroing pointers atomically. Anything that is a multiple of pointer size and at least pointer aligned might have pointers in it. All the code looks ok except for the 1-pointer-sized moves. Fixes #13160 Update #12552 Change-Id: Ib97d9b918fa9f4cc5c56c67ed90255b7fdfb7b45 Reviewed-on: https://go-review.googlesource.com/16668 Reviewed-by: Dmitry Vyukov <dvyukov@google.com> Run-TryBot: Keith Randall <khr@golang.org> TryBot-Result: Gobot Gobot <gobot@golang.org>
57 lines
871 B
ArmAsm
57 lines
871 B
ArmAsm
// Copyright 2014 The Go Authors. All rights reserved.
|
|
// Use of this source code is governed by a BSD-style
|
|
// license that can be found in the LICENSE file.
|
|
|
|
#include "textflag.h"
|
|
|
|
// void runtime·memclr(void*, uintptr)
|
|
TEXT runtime·memclr(SB), NOSPLIT, $0-8
|
|
MOVL ptr+0(FP), DI
|
|
MOVL n+4(FP), BX
|
|
XORL AX, AX
|
|
|
|
tail:
|
|
TESTL BX, BX
|
|
JEQ _0
|
|
CMPL BX, $2
|
|
JBE _1or2
|
|
CMPL BX, $4
|
|
JB _3
|
|
JE _4
|
|
CMPL BX, $8
|
|
JBE _5through8
|
|
CMPL BX, $16
|
|
JBE _9through16
|
|
MOVL BX, CX
|
|
SHRL $2, CX
|
|
REP
|
|
STOSL
|
|
ANDL $3, BX
|
|
JNE tail
|
|
RET
|
|
|
|
_1or2:
|
|
MOVB AX, (DI)
|
|
MOVB AX, -1(DI)(BX*1)
|
|
RET
|
|
_0:
|
|
RET
|
|
_3:
|
|
MOVW AX, (DI)
|
|
MOVB AX, 2(DI)
|
|
RET
|
|
_4:
|
|
// We need a separate case for 4 to make sure we clear pointers atomically.
|
|
MOVL AX, (DI)
|
|
RET
|
|
_5through8:
|
|
MOVL AX, (DI)
|
|
MOVL AX, -4(DI)(BX*1)
|
|
RET
|
|
_9through16:
|
|
MOVL AX, (DI)
|
|
MOVL AX, 4(DI)
|
|
MOVL AX, -8(DI)(BX*1)
|
|
MOVL AX, -4(DI)(BX*1)
|
|
RET
|