mirror of
https://github.com/golang/go
synced 2024-10-05 10:31:22 -06:00
71c1a7b777
This quiets all.bash noise for upcoming features we know about. The all.bash warnings will now only print for things not in next.txt (or in next.txt but not in the API). Once an API is frozen, we rename next.txt to a new frozen file (like go1.txt) Fixes #3651 R=golang-dev, r CC=golang-dev https://golang.org/cl/6218069
82 lines
1.8 KiB
Batchfile
82 lines
1.8 KiB
Batchfile
:: Copyright 2012 The Go Authors. All rights reserved.
|
|
:: Use of this source code is governed by a BSD-style
|
|
:: license that can be found in the LICENSE file.
|
|
@echo off
|
|
|
|
:: Keep environment variables within this script
|
|
:: unless invoked with --no-local.
|
|
if x%1==x--no-local goto nolocal
|
|
if x%2==x--no-local goto nolocal
|
|
setlocal
|
|
:nolocal
|
|
|
|
set GOBUILDFAIL=0
|
|
|
|
:: we disallow local import for non-local packages, if %GOROOT% happens
|
|
:: to be under %GOPATH%, then some tests below will fail
|
|
set GOPATH=
|
|
|
|
rem TODO avoid rebuild if possible
|
|
|
|
if x%1==x--no-rebuild goto norebuild
|
|
echo # Building packages and commands.
|
|
go install -a -v std
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
:norebuild
|
|
|
|
:: we must unset GOROOT_FINAL before tests, because runtime/debug requires
|
|
:: correct access to source code, so if we have GOROOT_FINAL in effect,
|
|
:: at least runtime/debug test will fail.
|
|
set GOROOT_FINAL=
|
|
|
|
echo # Testing packages.
|
|
go test std -short -timeout=120s
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
|
|
echo # runtime -cpu=1,2,4
|
|
go test runtime -short -timeout=120s -cpu=1,2,4
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
|
|
echo # sync -cpu=10
|
|
go test sync -short -timeout=120s -cpu=10
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
|
|
echo # ..\misc\dashboard\builder ..\misc\goplay
|
|
go build ..\misc\dashboard\builder ..\misc\goplay
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
|
|
:: TODO(brainman): disabled, because it fails with: mkdir C:\Users\ADMINI~1\AppData\Local\Temp\2.....\test\bench\: The filename or extension is too long.
|
|
::echo # ..\test\bench\go1
|
|
::go test ..\test\bench\go1
|
|
::if errorlevel 1 goto fail
|
|
::echo.
|
|
|
|
:: TODO: The other tests in run.bash.
|
|
|
|
echo # test
|
|
cd ..\test
|
|
set FAIL=0
|
|
go run run.go
|
|
if errorlevel 1 set FAIL=1
|
|
cd ..\src
|
|
echo.
|
|
if %FAIL%==1 goto fail
|
|
|
|
echo # Checking API compatibility.
|
|
go tool api -c ..\api\go1.txt -next ..\api\next.txt
|
|
if errorlevel 1 goto fail
|
|
echo.
|
|
|
|
echo ALL TESTS PASSED
|
|
goto end
|
|
|
|
:fail
|
|
set GOBUILDFAIL=1
|
|
|
|
:end
|