mirror of
https://github.com/golang/go
synced 2024-10-04 20:11:22 -06:00
718be3215f
(eliminate assumption of package global name space, make code easier to move between packages). R=r CC=golang-dev https://golang.org/cl/194072
84 lines
1.6 KiB
ArmAsm
84 lines
1.6 KiB
ArmAsm
// Copyright 2009 The Go Authors. All rights reserved.
|
|
// Use of this source code is governed by a BSD-style
|
|
// license that can be found in the LICENSE file.
|
|
|
|
//
|
|
// System call support for 386, Darwin
|
|
//
|
|
|
|
// func Syscall(trap int32, a1, a2, a3 int32) (r1, r2, err int32);
|
|
// func Syscall6(trap int32, a1, a2, a3, a4, a5, a6 int32) (r1, r2, err int32);
|
|
// Trap # in AX, args on stack above caller pc.
|
|
|
|
TEXT ·Syscall(SB),7,$0
|
|
CALL runtime·entersyscall(SB)
|
|
MOVL 4(SP), AX // syscall entry
|
|
// slide args down on top of system call number
|
|
LEAL 8(SP), SI
|
|
LEAL 4(SP), DI
|
|
CLD
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
INT $0x80
|
|
JAE ok
|
|
MOVL $-1, 20(SP) // r1
|
|
MOVL $-1, 24(SP) // r2
|
|
MOVL AX, 28(SP) // errno
|
|
CALL runtime·exitsyscall(SB)
|
|
RET
|
|
ok:
|
|
MOVL AX, 20(SP) // r1
|
|
MOVL DX, 24(SP) // r2
|
|
MOVL $0, 28(SP) // errno
|
|
CALL runtime·exitsyscall(SB)
|
|
RET
|
|
|
|
TEXT ·Syscall6(SB),7,$0
|
|
CALL runtime·entersyscall(SB)
|
|
MOVL 4(SP), AX // syscall entry
|
|
// slide args down on top of system call number
|
|
LEAL 8(SP), SI
|
|
LEAL 4(SP), DI
|
|
CLD
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
INT $0x80
|
|
JAE ok6
|
|
MOVL $-1, 32(SP) // r1
|
|
MOVL $-1, 36(SP) // r2
|
|
MOVL AX, 40(SP) // errno
|
|
CALL runtime·exitsyscall(SB)
|
|
RET
|
|
ok6:
|
|
MOVL AX, 32(SP) // r1
|
|
MOVL DX, 36(SP) // r2
|
|
MOVL $0, 40(SP) // errno
|
|
CALL runtime·exitsyscall(SB)
|
|
RET
|
|
|
|
TEXT ·RawSyscall(SB),7,$0
|
|
MOVL 4(SP), AX // syscall entry
|
|
// slide args down on top of system call number
|
|
LEAL 8(SP), SI
|
|
LEAL 4(SP), DI
|
|
CLD
|
|
MOVSL
|
|
MOVSL
|
|
MOVSL
|
|
INT $0x80
|
|
JAE ok1
|
|
MOVL $-1, 20(SP) // r1
|
|
MOVL $-1, 24(SP) // r2
|
|
MOVL AX, 28(SP) // errno
|
|
RET
|
|
ok1:
|
|
MOVL AX, 20(SP) // r1
|
|
MOVL DX, 24(SP) // r2
|
|
MOVL $0, 28(SP) // errno
|
|
RET
|